ESP32 MQTT – публикация и подписка с помощью Arduino IDE

В этом проекте показано, как использовать протокол связи MQTT с ESP32 для публикации сообщений и подписки на темы. В качестве примера мы опубликуем показания датчика BME280 на панели управления Node-RED и будем управлять выходом ESP32. ESP32 мы будем программировать с помощью Arduino IDE. 

В этом примере есть приложение Node-RED, которое управляет выходами ESP32 и получает показания датчиков от ESP32 с использованием протокола связи MQTT. Приложение Node-RED работает на Raspberry Pi.

Мы будем использовать брокер Mosquitto, установленный на том же Raspberry Pi. Брокер отвечает за получение всех сообщений, их фильтрацию, решение о том, кто в них заинтересован, и публикацию сообщений всем подписанным клиентам.

На следующем рисунке показан обзор того, что мы собираемся делать в этом уроке.

• Приложение Node-RED публикует сообщения (« on » или « off ») в теме esp32/output . ESP32 подписан на эту тему. Таким образом, он получает сообщение «включено» или «выключено», чтобы включить или выключить светодиод.
• ESP32 публикует температуру в теме esp32/temperature , а влажность — в теме esp32/humidity . Приложение Node-RED подписано на эти темы. Таким образом, он получает показания температуры и влажности, которые можно отобразить, например, на графике или датчике.

Предварительные условия

• Вы должны быть знакомы с Raspberry Pi 
• На Raspberry Pi должна быть установлена ​​операционная система Raspbian.
• Узнайте  , что такое MQTT и как он работает .

Требуемые детали

Вот детали, необходимые для сборки схемы:

• Raspberry Pi – прочтите Лучшие стартовые наборы Raspberry Pi 3
• Плата ESP32 DOIT DEVKIT V1  – прочтите обзор и сравнение плат разработки ESP32
• Сенсорный модуль BME280
• 1x 5 мм светодиод
• 1x резистор 220 Ом
• Макет
• Перемычки

Представляем сенсорный модуль BME280

Сенсорный модуль BME280 считывает температуру, влажность и давление. Поскольку давление меняется с высотой, вы также можете оценить высоту. Однако в этом уроке мы просто будем измерять температуру и влажность. Существует несколько версий этого сенсорного модуля, но мы используем ту, которая показана на рисунке ниже.

Датчик может обмениваться данными с использованием протоколов связи SPI или I2C (есть модули этого датчика, которые обмениваются данными только с I2C, они имеют всего четыре контакта).

Чтобы использовать протокол связи SPI, используйте следующие контакты:

• SCK – это вывод SPI Clock.
• СДО – МИСО
• СОИ – МОСИ
• CS – Выбор чипа

Для использования протокола связи I2C датчик использует следующие контакты:

• SCK – вывод SCL
• SDI – вывод SDA

Схематическое изображение

Мы собираемся использовать связь I2C с сенсорным модулем BME280. Для этого подключите датчик к контактам ESP32 SDA и SCL, как показано на следующей принципиальной схеме.

Мы также будем управлять выходом ESP32 — светодиодом, подключенным к GPIO 4.

Вот как должна выглядеть ваша схема:

Подготовка Arduino IDE

Для Arduino IDE существует надстройка, которая позволяет программировать ESP32 с использованием Arduino IDE и ее языка программирования. Следуйте одному из следующих руководств, чтобы подготовить вашу Arduino IDE к работе с ESP32, если вы еще этого не сделали.

• Инструкции для Windows  — плата ESP32 в Arduino IDE
• Инструкции для Mac и Linux  — плата ESP32 в Arduino IDE

Убедившись, что у вас установлено дополнение ESP32, вы можете продолжить работу с этим руководством.

Установка библиотеки PubSubClient

Библиотека PubSubClient предоставляет клиент для простого обмена сообщениями о публикации/подписке с сервером, поддерживающим MQTT (по сути, позволяет вашему ESP32 взаимодействовать с Node-RED).

1. Нажмите здесь, чтобы загрузить библиотеку PubSubClient . В папке «Загрузки» у вас должна быть папка .zip.
2. Разархивируйте папку .zip , и вы получите папку pubsubclient-master.
3. Переименуйте папку из pubsubclient-masterопубликовать субклиенту
4. Переместите папку pubsubclient в папку установочных библиотек Arduino IDE.
5. Затем снова откройте Arduino IDE.

В библиотеке имеется несколько примеров эскизов. См. Файл > Примеры > PubSubClient в программном обеспечении Arduino IDE.

Важно:  PubSubClient не полностью совместим с ESP32, но пример, представленный в этом руководстве, во время наших тестов работал очень надежно.

Установка библиотеки BME280

Для снятия показаний с сенсорного модуля BME280 мы воспользуемся библиотекой Adafruit_BME280 . Выполните следующие шаги, чтобы установить библиотеку в вашу Arduino IDE:

1. Нажмите здесь, чтобы загрузить библиотеку Adafruit-BME280. В папке «Загрузки» у вас должна быть папка .zip.
2. Разархивируйте папку .zip, и вы получите папку Adafruit-BME280-Library-master.
3. Переименуйте папку изAdafruit-BME280-Библиотека-мастерв Adafruit_BME280_Library
4. Переместите папку Adafruit_BMPE280_Library в папку установочных библиотек Arduino IDE.
5. Наконец, снова откройте Arduino IDE.

Альтернативно вы можете перейти в «Скетч» > «Включить библиотеку» > «Управление библиотеками » и ввести « adafruit bme280 » для поиска библиотеки. Затем нажмите «Установить».

Установка библиотеки Adafruit_Sensor

Чтобы использовать библиотеку BME280, вам также необходимо установить библиотеку Adafruit_Sensor . Выполните следующие шаги для установки библиотеки:

1. Нажмите здесь, чтобы загрузить  библиотеку Adafruit_Sensor. В папке «Загрузки» у вас должна быть папка .zip.
2. Разархивируйте папку .zip, и вы получите папку Adafruit_Sensor-master.
3. Переименуйте папку изAdafruit_Sensor-masterв Adafruit_Sensor
4. Переместите папку Adafruit_Sensor  в папку установочных библиотек Arduino IDE.
5. Наконец, снова откройте Arduino IDE.

Загрузка кода

Теперь вы можете загрузить следующий код в свой ESP32. В коде есть комментарии, где нужно внести изменения. Вам необходимо отредактировать код, указав свой собственный SSID, пароль и IP-адрес Raspberry Pi.

/*********
  Rui Santos
  Complete project details at https://randomnerdtutorials.com  
*********/

#include <WiFi.h>
#include <PubSubClient.h>
#include <Wire.h>
#include <Adafruit_BME280.h>
#include <Adafruit_Sensor.h>

// Replace the next variables with your SSID/Password combination
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Add your MQTT Broker IP address, example:
//const char* mqtt_server = "192.168.1.144";
const char* mqtt_server = "YOUR_MQTT_BROKER_IP_ADDRESS";

WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;
char msg[50];
int value = 0;

//uncomment the following lines if you're using SPI
/*#include <SPI.h>
#define BME_SCK 18
#define BME_MISO 19
#define BME_MOSI 23
#define BME_CS 5*/

Adafruit_BME280 bme; // I2C
//Adafruit_BME280 bme(BME_CS); // hardware SPI
//Adafruit_BME280 bme(BME_CS, BME_MOSI, BME_MISO, BME_SCK); // software SPI
float temperature = 0;
float humidity = 0;

// LED Pin
const int ledPin = 4;

void setup() {
  Serial.begin(115200);
  // default settings
  // (you can also pass in a Wire library object like &Wire2)
  //status = bme.begin();  
  if (!bme.begin(0x76)) {
    Serial.println("Could not find a valid BME280 sensor, check wiring!");
    while (1);
  }
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);

  pinMode(ledPin, OUTPUT);
}

void setup_wifi() {
  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* message, unsigned int length) {
  Serial.print("Message arrived on topic: ");
  Serial.print(topic);
  Serial.print(". Message: ");
  String messageTemp;
  
  for (int i = 0; i < length; i++) {
    Serial.print((char)message[i]);
    messageTemp += (char)message[i];
  }
  Serial.println();

  // Feel free to add more if statements to control more GPIOs with MQTT

  // If a message is received on the topic esp32/output, you check if the message is either "on" or "off". 
  // Changes the output state according to the message
  if (String(topic) == "esp32/output") {
    Serial.print("Changing output to ");
    if(messageTemp == "on"){
      Serial.println("on");
      digitalWrite(ledPin, HIGH);
    }
    else if(messageTemp == "off"){
      Serial.println("off");
      digitalWrite(ledPin, LOW);
    }
  }
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect("ESP8266Client")) {
      Serial.println("connected");
      // Subscribe
      client.subscribe("esp32/output");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}
void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  long now = millis();
  if (now - lastMsg > 5000) {
    lastMsg = now;
    
    // Temperature in Celsius
    temperature = bme.readTemperature();   
    // Uncomment the next line to set temperature in Fahrenheit 
    // (and comment the previous temperature line)
    //temperature = 1.8 * bme.readTemperature() + 32; // Temperature in Fahrenheit
    
    // Convert the value to a char array
    char tempString[8];
    dtostrf(temperature, 1, 2, tempString);
    Serial.print("Temperature: ");
    Serial.println(tempString);
    client.publish("esp32/temperature", tempString);

    humidity = bme.readHumidity();
    
    // Convert the value to a char array
    char humString[8];
    dtostrf(humidity, 1, 2, humString);
    Serial.print("Humidity: ");
    Serial.println(humString);
    client.publish("esp32/humidity", humString);
  }
}

Посмотреть исходный код

Этот код публикует показания температуры и влажности по темам esp32/temperature и esp32/humidity через протокол MQTT.

ESP32 подписан на тему esp32/output  для получения сообщений, опубликованных по этой теме приложением Node-RED. Затем в соответствии с полученным сообщением включает или выключает светодиод.

Подписка на темы MQTT

В функции reconnect() вы можете подписаться на темы MQTT. В этом случае ESP32 подписан только на esp32/output :

client.subscribe("esp32/output");

В  функции обратного вызова () ESP32 получает сообщения MQTT подписанных тем. В соответствии с темой и сообщением MQTT он включает или выключает светодиод:

// If a message is received on the topic esp32/output, you check if the message is either "on" or "off". 
// Changes the output state according to the message
if (String(topic) == "esp32/output") {
  Serial.print("Changing output to ");
  if (messageTemp == "on") {
    Serial.println("on");
    digitalWrite(ledPin, HIGH);
  }
  else if (messageTemp == "off") {
    Serial.println("off");
    digitalWrite(ledPin, LOW);
  }
}

Публикация сообщений MQTT

В цикле() новые показания публикуются каждые 5 секунд:

if (now - lastMsg > 5000) { ... }

По умолчанию ESP32 отправляет температуру в градусах Цельсия, но вы можете раскомментировать последнюю строку, чтобы отправить температуру в градусах Фаренгейта:

// Temperature in Celsius
temperature = bme.readTemperature(); 
// Uncomment the next line to set temperature in Fahrenheit 
// (and comment the previous temperature line)
//temperature = 1.8 * bme.readTemperature() + 32; // Temperature in Fahrenheit

Вам необходимо преобразовать переменную с плавающей запятой температуры в массив символов, чтобы можно было опубликовать показания температуры в теме esp32/temperature :

// Convert the value to a char array
char tempString[8];
dtostrf(temperature, 1, 2, tempString);
Serial.print("Temperature: ");
Serial.println(tempString);
client.publish("esp32/temperature", tempString);

Тот же процесс повторяется для публикации показаний влажности в теме esp32/humidity :

humidity = bme.readHumidity();
// Convert the value to a char array
char humString[8];
dtostrf(humidity, 1, 2, humString);
Serial.print("Humidity: ");
Serial.println(humString);
client.publish("esp32/humidity", humString);

Создание потока Node-RED

Перед созданием потока вам необходимо установить на Raspberry Pi:

• Узел-RED
• Панель управления Node-RED
• Москитто Брокер

После этого импортируйте предоставленный поток Node-RED. Перейдите в  репозиторий GitHub  или щелкните рисунок ниже, чтобы просмотреть необработанный файл, и скопируйте предоставленный код.

Затем в окне Node-RED в правом верхнем углу выберите меню и выберите «  Импорт»   >  «Буфер обмена» .

Затем вставьте предоставленный код и нажмите  «Импортировать» .

Должны загрузиться следующие узлы:

После внесения любых изменений нажмите  кнопку «Развернуть»  , чтобы сохранить все изменения.

Интерфейс Node-RED

Теперь ваше приложение Node-RED готово. Чтобы получить доступ к пользовательскому интерфейсу Node-RED и посмотреть, как выглядит ваше приложение, откройте любой браузер в локальной сети и введите:

http:// Ваш_RPi_IP_адрес:1880 /ui

Ваше приложение должно выглядеть, как показано на следующем рисунке. Вы можете управлять включением и выключением светодиода с помощью переключателя или просматривать показания температуры на графике и значения влажности на датчике.

Демонстрация

Посмотрите следующее видео, чтобы увидеть живую демонстрацию:

Откройте последовательный монитор Arduino IDE, чтобы просмотреть получаемые и публикуемые сообщения MQTT.

Подведение итогов

Таким образом, мы показали вам основные концепции, которые позволяют вам включать освещение и контролировать датчики с помощью ESP32 с использованием Node-RED и протокола связи MQTT. Вы можете использовать этот пример для интеграции в свою собственную систему домашней автоматизации, управления дополнительными выходами или мониторинга других датчиков.

Вам также может быть интересно прочитать:

• Изучите ESP32 с помощью курса Arduino IDE
• Alexa (Echo) с ESP32 и ESP8266 — реле с голосовым управлением
• Создайте универсальный шилд для метеостанции ESP32
• ESP32 Публикация показаний датчиков в Google Sheets
• ESP32 с DHT11 Веб-сервер температуры и влажности DHT22
• Веб-сервер ESP32 с Arduino IDE